/*
All Rights Reserved @ 2008 by Sin L.
Animation Copy tool version 2.5 Written by Sin Loh, jcsin@hotmail.com
<<--Description-->>
The "Animation Copy" allow maya users to record the pose, or animation in a text file
that stored in a directory the users have picked; the directory the users picked
will be recorded down(in anmPose_userPrefs.mel) so users don't have to go in to pick
the directory again next time they start the tool. You could also type the directory path in 
the directory textfield and press "Enter" on the numpad to save the directory info. 
Pose and Animation keys are stored in .pose and .anm respectively to distinguish the format, 
users can open the file with notepad and edit the key datas as they want. 
The script is copying and pasting the animation keys based on the name of the nodes, 
so identical node names are required to get the keys transfered/copied over.
The second function in this toolset is the "Animation Transfer", it works differently from
the above mentioned. This script can do a batch transfer of animation keys to a different character
that have the same node names.

<<--Known bugs-->>
1) When the users' Maya scene has same node names, which create pipe like xyx|abc resulting in error.
While this is not an actual bug bcos you are not supposed to have duplicated names, here is the 
solution: Find the duplicated node names and rename them uniquely. Or use my renameDuplicate mel script.
2) When the maya scene contain myterious nodes like "unknown". delete the "unknown" node would fix the problem.
You can use the script to fix the problem--> delete `ls -type "unknown"`;

Run "my_AnmCopyWindowProc" after you source the scritps.

Please feel free to give me feedbacks and questions to my email, jcsin@hotmail.com
*/

global string $anmPoseUserPref = "anmPose_userPrefs.mel"; //the name of pref. mel file is editable here.
global string $anmPoseFileName;
$anmPoseFileName =( `internalVar -userPrefDir` + $anmPoseUserPref ); //this is the userpref directory + filename

//Check the status of "anmPose_userPrefs.mel", if it doesn't exist, create one.
global proc checkAnmPrefstatus()
{
	global string $anmPoseFileName; 
	int $filestatus = `filetest -f $anmPoseFileName`;
	if ($filestatus == 0)
	{
	$fileId=`fopen $anmPoseFileName`;
	fclose $fileId;
	}
}
	
	
	//procedure for keeping the user's directory path in the tool, fprinted in the anmPose_userPrefs.mel
	//so even the user close the window, the path info in the tool will be kept.
	global proc sin_setAsDefaultDir()
 	{
	 	global string $anmPoseUserPref;
	 	global string $anmPoseFileName;
	 	
	 	string $dirText = `textField -q -text as_savedirTF`; 	
	 	int $filestatus = `filetest -f $anmPoseFileName`;
	 	if ($filestatus == 1) 
	 	{
	 	$fileId=`fopen $anmPoseFileName "w"`;
	 	fprint $fileId $dirText;
	 	fclose $fileId;
		} else
			{
			$fileId=`fopen $anmPoseFileName "w"`;
			fprint $fileId $dirText;
			fclose $fileId;
			}
	}
 	
 	//procedure for reading the user's directory path in the userpref.mel
 	
 	global proc sin_readAnmPose_userPrefs()
 	{
 	global string $anmPoseUserPref;	
 	global string $anmPoseFileName;
 	
 	int $filetest = `filetest -f $anmPoseFileName`;
 	if ($filetest == 1)
	 	{
		 	$fileId=`fopen $anmPoseFileName "r"`;
		 	while ( !`feof $fileId` ) {
		 		string $nextWord = `fgetword $fileId`;
		 		if ( size( $nextWord ) > 0 ) {
					textField -e -text $nextWord as_savedirTF;
		 			//print ( $nextWord + "\n" );
		 		}
		 	}
		 	fclose $fileId; 
		}
	}
	
	
//this is the command will be executed when press enter in the textfield	
global proc textFieldEnterCommand()
{
sin_setAsDefaultDir;	
sin_readAnmPose_userPrefs;
as_populateDirFileProc;	
}	
	
// return procedure to find all nodes with have keys
global proc string [] ac_findNodesWithKeysProc()

{
	//This will return nodes and thier attributes
	string $returnAllKeyNodes[];
	
	string $finalNodes[]; 
	
	int $inclcamCBstate = `checkBox -q -v inclcamCB`;
	int $inclcstCBstate = `checkBox -q -v inclcstCB`;
	
	if ($inclcamCBstate == 0 && $inclcstCBstate == 1 )
	{
	string $allNodes[] =`ls -type transform`;
	string $lsCamerasRemoved[] =`listCameras`;
   	$finalNodes = stringArrayRemove($lsCamerasRemoved, $allNodes);
	}
	if ($inclcamCBstate == 1 && $inclcstCBstate == 0 )
	{
	string $allNodes[] =`ls -type transform`;
	string $lsConstraintRemoved[] =`ls -type constraint`;
   	$finalNodes = stringArrayRemove($lsConstraintRemoved, $allNodes);
	}
	
	if ($inclcamCBstate == 0 && $inclcstCBstate == 0 )
	{
	string $allNodes[] =`ls -type transform`;
	string $lsConstraintRemoved[] =`ls -type constraint`;
	string $lsCamerasRemoved[] =`listCameras`;
   	string $NoConstraintNodes[] = stringArrayRemove($lsConstraintRemoved, $allNodes);
	$finalNodes = stringArrayRemove($lsCamerasRemoved, $NoConstraintNodes);
	}
	
	if ($inclcamCBstate == 1 && $inclcstCBstate == 1 )
	{
	$finalNodes =`ls -type transform`;
	}
				
		for ($x=0; $x<size($finalNodes) ; $x++)
			{
			int $allNodeKeysNum=`keyframe -q -keyframeCount $finalNodes[$x]`;
			if ($allNodeKeysNum > 0)
					{
						string $attrOnly[] =`listAttr -k $finalNodes[$x]`;
							for ($y=0; $y<size($attrOnly); $y++)
							{
								string $nodesAttrs = $finalNodes[$x] + "." + $attrOnly[$y];
									
										int $singleNodeKeysNum=`keyframe -q -keyframeCount $nodesAttrs`;
								
										if ($singleNodeKeysNum > 0)
											{
												$returnAllKeyNodes[size($returnAllKeyNodes)] = $nodesAttrs;
											}
							}
					}
			}
	
	return $returnAllKeyNodes;
}

//return procedure to find keys from selected nodes only.
global proc string [] as_findSelectedNodesProc()

{
	
	//This will return selected nodes and thier attributes
	string $returnSelectedNodes[];
	string $allnode[] =`textScrollList -q -ai as_selectedNodeTSL`;

	for ($x=0; $x<size($allnode) ; $x++)
		{
			string $attrOnly[] =`listAttr -k $allnode[$x]`;
			
			for ($y=0; $y<size($attrOnly); $y++)
			{
				string $nodesAttrs = $allnode[$x] + "." + $attrOnly[$y];
				int $allNodeKeysNum =`keyframe -q -keyframeCount $nodesAttrs`;
				if ($allNodeKeysNum > 0)
				{
				$returnSelectedNodes[size($returnSelectedNodes)] = $nodesAttrs;
				}							
			}
				
		}
	
	return $returnSelectedNodes;

}



// Copy All or only Selected Nodes that have animation keys
global proc as_printToFileProc()
{
	sin_setAsDefaultDir;
	//Print all to file, with time range option available
	global string $dirname;
	$dirName =`textField -q -text as_savedirTF`;
	string $anmName =`textField -q -text as_AnmNameTF`;
		
	global string $outputName;
	$outputName = ($dirName + "/" + $anmName + ".anm");
		
		//After the error checking and confirm overwrite, the exists file will be deleted.
		int $fileExist =`filetest -f $outputName`;
		//print $fileExist;
		if ($fileExist == 1) 
			{										
				sysFile -delete $outputName;
			}	
		
	//choose either print all to file, or print only selected nodes to file
	string $copyAttributesAll[];
	int $checkCB = `checkBox -q -v copylistedCB`; //if only selected
	if ($checkCB == 1)
	{
		$copyAttributesAll = as_findSelectedNodesProc();
		if (size($copyAttributesAll) < 1 )
		{
			error "Nothing in the list.";
		}
		
	} 
		else
	{		
		$copyAttributesAll = ac_findNodesWithKeysProc(); //find all nodes with keys
	}
	
	 	 	
	
for ($x=0; $x<size($copyAttributesAll); $x++ ) 
	{
	
		$fileId=`fopen $outputName`;
		
		fprint $fileId ("\n" + "nodeAttrType : ");
		fprint $fileId ($copyAttributesAll[$x] + "\n");
		//print $copyAttributesAll[$x];
		
		//This is the procedure to get animation keys and curve behaviors from desired time range... 
		
		int $copyTimeRangeRBState = `radioButton -q -sl timeRangeRB`;
 		int $minTime = `playbackOptions -q -minTime`;
		int $maxTime = `playbackOptions -q -maxTime`;			
		
		
		string $timeRange = "";
		if( $copyTimeRangeRBState == 1)
		{
		$timeRange = " -time (\"" + $minTime + ":" + $maxTime + "\") ";
		
		//In order to set a key at the first frame and last frame in the time range,
		//and without sacrifice the curve behavior, is by using copy keys with segment option.
		
		copyKey -time ($minTime + ":" + $maxTime) -float ($minTime + ":" + $maxTime) -option curve -hierarchy none -controlPoints 0 -shape 1 $copyAttributesAll[$x];
		pasteKey -time $minTime -float $minTime -option merge -copies 1 -connect 0 -timeOffset 0 -floatOffset 0 -valueOffset 0 $copyAttributesAll[$x];

		} else
		 	
				 	{	
				 		//I need to find the very first "time" that have keyframe
				 		selectKey -time ":" $copyAttributesAll; //need to select an object first
						float $allKeys[3] = sort(`keyframe -q -sl`); //sort the time so we know the very first frame that have keys
						select -cl; // just to clear the selection
						//print ("The first keyframe is at time " + $allKeys[0]);
				 		//so I found the very first key occurs at frame $allKeys[0], then I set keys 
				 		//on every attributes on that frame to avoid some curve got keys not from the very start;
				 		currentTime $allKeys[0];    //go to the first frame we found and setkey
				 		setKeyframe $copyAttributesAll[$x] ;
				 		
				 	}
		
		float $keyframesAll[]= eval("keyframe" + $timeRange +  "-query -valueChange -timeChange " + $copyAttributesAll[$x]);
						
		//float $keyframesAll[]= `keyframe $timeRange -query -valueChange -timeChange $copyAttributesAll[$x]`;
		fprint $fileId ("keyframes : " );
		
		 			//this is to separate the float array above to be keyframes and the key values
					for ($y=0, $z=1; $y<size($keyframesAll),$z<size($keyframesAll); $y += 2, $z +=2 )
					 
					{
					 	float $frames;
					 	$frames = $keyframesAll[$y];
					  
					  //I fixed the script on the paste animation side so below it's unecessary anymore.
					  //if timeRange option is on, the keyframe should reset to start at frame 1,
					  //so later could paste them on the desired frame easier
					  /*if( $copyTimeRangeRBState == 1) 
						 	{
						 	float $minusFrames = ($keyframesAll[0]	- 1);
						 	$frames = ($keyframesAll[$y] - $minusFrames);
						 	}	 */
					 			 		  
					 	float $keyValues;
					 	$keyValues = $keyframesAll[$z];
					 			 	
						fprint $fileId ($frames + " " + $keyValues + " ") ;	
					}
	
			//Now starting to get the curve behaviours etc.	
		 		
			//get weightedTangents
			int $weightedTangentsAll[]= `keyTangent -q -weightedTangents $copyAttributesAll[$x]`;
			fprint $fileId ("\n" + "weightedTangents : ");
			fprint $fileId ($weightedTangentsAll[0] + " ");
		
			//Get lock
			int $Lock[]= eval ("keyTangent" + $timeRange + "-q -lock " + $copyAttributesAll[$x]);
			fprint $fileId ("\n" + "lock : ");
			for ($each in $Lock)
			{
				fprint $fileId ($each + " ");
			}
			
			//Get Weightlock
			int $weightLock[]= eval ("keyTangent" + $timeRange + "-q -weightLock " + $copyAttributesAll[$x]);
			fprint $fileId ("\n" + "weightLock : ");
			for ($each in $weightLock)
			{
				fprint $fileId ($each + " ");
			}
			
			//Get Curve inWeights		
			float $inWeightAll[]=eval ("keyTangent" + $timeRange + "-q -inWeight " + $copyAttributesAll[$x]);
			fprint $fileId ("\n" + "inWeight : ");
				for ($a=0; $a<size($inWeightAll); $a++ )
				{
					fprint $fileId ($inWeightAll[$a] + " ");
				}
			
			//Get Curve OutWeights			
			float $outWeightAll[]=eval ("keyTangent" + $timeRange + "-q -outWeight " + $copyAttributesAll[$x]);
			fprint $fileId ("\n" + "outWeight : ");
				for ($b=0; $b<size($outWeightAll); $b++ )
				{
					fprint $fileId ($outWeightAll[$b] + " ");
				}
			
			//Get Curve inAngle	
			float $inAngleAll[]=eval ("keyTangent" + $timeRange + "-q -inAngle " + $copyAttributesAll[$x]);	
			fprint $fileId ("\n" + "inAngle : ");
				for ($c=0; $c<size($inAngleAll); $c++ )
				{
					fprint $fileId ($inAngleAll[$c] + " ");
				}
			
			//Get Curve OutAngle		
			float $outAngleAll[]=eval ("keyTangent" + $timeRange + "-q -outAngle " + $copyAttributesAll[$x]);
			fprint $fileId ("\n" + "outAngle : ");
				for ($d=0; $d<size($outAngleAll); $d++ )
				{
					fprint $fileId ($outAngleAll[$d] + " ");
				}
			
			//Get Cruve inTangent										
			string $inTangentTypeAll[] = eval ("keyTangent" + $timeRange + "-q -inTangentType " + $copyAttributesAll[$x]);
			
			fprint $fileId ("\n" + "inTangentType : ");
			for ($y=0; $y<size($inTangentTypeAll); $y++ ) 
			{
				fprint $fileId ($inTangentTypeAll[$y] + " ");
			}
			
			//Get Curve OutTangent
			string $outTangentTypeAll[]= eval ("keyTangent" + $timeRange + "-q -outTangentType " + $copyAttributesAll[$x]);
			fprint $fileId ("\n" + "outTangentType : ");
			for ($z=0; $z<size($outTangentTypeAll); $z++ )
			{
			 fprint $fileId ($outTangentTypeAll[$z] + " ");
			}
				
						// this is to undo the setKeyframe at the top.			
						undo setKeyframes;						
						
				
		fclose $fileId;															
											
	
		//populate new filelist		
		as_populateDirFileProc;	
		textScrollList -e -si ($anmName + ".anm") as_AnmStoringTSL;

}

}


//delete file confirmation window
global proc as_deleteConfirmWinProc()

{
	string $outputTSL[] =`textScrollList -q -si as_AnmStoringTSL`;
	if (size($outputTSL)>=1)
 {
		string $confirm =`confirmDialog 
						-title "Are you sure?" 
						-message ("Do you want to delete " + $outputTSL[0] + "\n" + "from the window system?")
				 		-button "Ok" -button "Cancel" -defaultButton "Ok"
				 		-cancelButton "Cancel" -dismissString "Cancel"`;
		
		if  ($confirm == "Ok")
		{
		as_delSelectedTSLFile;
		}

 }
 else{
	 error "Hellooo!! There is nothing to delete! Dude! \n";
 }
}

//when select a item from textscrollist, it will appear the name at the textfield.
global proc as_fillDirNameProc()
{
	string $buffer[];
	string $selItem[] =`textScrollList -q -selectItem as_AnmStoringTSL`;
	tokenize $selItem[0] "." $buffer;
	textField -e -text $buffer[0] as_AnmNameTF;
}

//pick a directory folder
global proc as_pickDirectoryProc( string $filename, string $fileType )
{
	int $poseRBOnOff = `radioButton -q -sl poseRB`;
	string $fileList[];
	if ($poseRBOnOff == 1)
	{
 	$fileList =`getFileList -folder ($filename + "/") -filespec "*.pose"`;
	} 
	else
	{
	$fileList =`getFileList -folder ($filename + "/") -filespec "*.anm"`;
	
	}
	textScrollList -e -ra as_AnmStoringTSL;
	for ($each in $fileList)
		{
			textScrollList -e -append $each as_AnmStoringTSL;
		}

	textField -e -text ($filename + "/") as_savedirTF;

sin_setAsDefaultDir;//after pick the directory, the path will be recorded in usepref.mel
}

global proc as_pickDirProc()
{
	fileBrowserDialog -m 4 -fc "as_pickDirectoryProc" -an "Choose a directory" -om "Import";
}

//refresh the textscrollist.
global proc as_populateDirFileProc()
	
{
	string $dirName =`textField -q -text as_savedirTF`;
	int $poseRBOnOff = `radioButton -q -sl poseRB`;
	string $fileList[];
	if ($poseRBOnOff == 1)
	{
		$fileList =`getFileList -fld ($dirName + "/") -filespec "*.pose"`;
	}
	else
	{
		$fileList =`getFileList -fld ($dirName + "/") -filespec "*.anm"`;
	}
			
			textScrollList -e -ra as_AnmStoringTSL;
			for ($each in $fileList)
			{
			textScrollList -e -append $each as_AnmStoringTSL;
			}
			
			string $temp[] =`textScrollList -q -ai as_AnmStoringTSL`;
			if (size($temp)>0)
			{
			textScrollList -e -sii 1 as_AnmStoringTSL;
			}

}

//add selected nodes to textscrolist
global proc as_addSelectedProc()
{
	string $sel[]=`ls -sl`;
	string $list[] = `textScrollList -q -ai as_selectedNodeTSL`;
	string $finalList[] = stringArrayCatenate( $sel, $list ) ;
   	string $shorterList[] = stringArrayRemoveDuplicates($finalList);
	$shorterList = `sort $shorterList`;
	textScrollList -e -ra as_selectedNodeTSL;
	
	for ($each in $shorterList)
	{
	textScrollList -e -a $each as_selectedNodeTSL;
	}
	
}

//to remove item from textscrollist
global proc as_removeSelectedProc()
{
	string $selecteditem[] = `textScrollList -q -si as_selectedNodeTSL`;
	for ($each in $selecteditem){ 
	textScrollList -e -ri $each as_selectedNodeTSL;
	select -cl;
	}
}

//clear everything from textscrollist
global proc as_clearListSelectedNodeTSLProc()
{
textScrollList -e -ra as_selectedNodeTSL;
select -cl;
}

////////////////////////////////////////////////////////
/////////////////////////////////////////////////////////
//Paste Animation procedures start here//////////////////
////////////////////////////////////////////////////////
////////////////////////////////////////////////////////

global proc float findExactKeyframe( float $firstKeyFrame, float $currentTime, float $keyFrame)
{

float $keyFrameSet;
//This is to find value the differences between the first keyframe and current time
//so the script could find the exact offset values of the keyframes got pasted.
//reason is negative and positive of the current time possibilites animators would choose

int $frameDiff =  $firstKeyFrame - $currentTime;
$frameDiff = abs ($frameDiff); //I just want to know the differences, no negative value needed

if ($firstKeyFrame <= $currentTime) //reason is negative and positive current time possibilites animator would choose
{
	
//if the current time value is equal or bigger than the keyFrame,then using "ADD", else use "Substract"
$keyFrameSet = ($keyFrame + $frameDiff);
	
} else
	{
	$keyFrameSet = ($keyFrame - $frameDiff);	
	}
	
	return $keyFrameSet;
}


global proc as_pasteAnmProc()
{

	string $dirName =`textField -q -text as_savedirTF`;
	string $fileName[] =`textScrollList -q -si as_AnmStoringTSL`;
	if (size($fileName)<1)	
	{
		error "Select an animation.";
	}
	
	int $fileId=`fopen ($dirName + "/" + $fileName[0]) "r"`;
	
	float $currentTime =`currentTime -q`;
	string $nodeAttrType[];
	string $nodeName;
	string $allKeyframes[];
	string $weightedTangents[];
	string $Lock[];
	string $weightLock[];
	string $inTangentType[];
	string $outTangentType[];
	string $inWeight[];
	string $outWeight[];
	string $inAngle[];
	string $outAngle[];
	float $keyFrame;
	float $keyValue;
	float $keyFrameSet;
	float $firstKeyFrame;
	
 	while (!`feof $fileId` ) 
	{ 
	 	$nextLine = `fgetline $fileId`;
						 
		if (size ($nextLine) > 0)
		{
			string $buffer[];
			tokenize $nextLine ":" $buffer;
			
			if ( startsWith (strip($buffer[0]), "nodeAttrType") )
			{				
				tokenize (strip($buffer[1])) "." $nodeAttrType;
				$nodeName = ($nodeAttrType[0] + "." + $nodeAttrType[1]);
			}
			
			if ( startsWith (strip($buffer[0]), "keyframes") )
			{				
				tokenize (strip($buffer[1])) " " $allKeyframes;
				if (`objExists $nodeName`)
				{
					int $checkAttrKeyable = `getAttr -k $nodeName`;
					int $checkAttrLock = `getAttr -l $nodeName`;
					if ($checkAttrLock == 0 && $checkAttrKeyable == 1 )
					{
						 
						$firstKeyFrame = float ($allKeyframes[0]); //find the first keyframe only.
						
						for ($x=0; $x <size($allKeyframes); $x = $x + 2)
						{
							$keyFrame = float ($allKeyframes[$x]);
							$keyValue = float ($allKeyframes[$x+1]);
							
							//I made a global proc float for the scripts below; 
							/* 
							//This is to find value the differences between the first keyframe and current time
							//so the script could find the exact offset values of the keyframes got pasted.
							
							int $frameDiff =  $firstKeyFrame - $currentTime;
							$frameDiff = abs ($frameDiff); //I just want to know the differences, no negative value needed
							
							if ($firstKeyFrame <= $currentTime) //reason is negative and positive current time possibilites animator would choose
							{
							$keyFrameSet = ($keyFrame + $frameDiff);
								
							} else
								{
								$keyFrameSet = ($keyFrame - $frameDiff);	
								}*/  
								
							//I made a global proc float for the above scripts;
								
							$keyFrameSet = `findExactKeyframe $firstKeyFrame $currentTime $keyFrame`;	//refer to above
																
							setKeyframe -t $keyFrameSet -v $keyValue -attribute $nodeAttrType[1] $nodeAttrType[0];
								
						} 
					}	else
								{
									print ($nodeName + " is locked or not keyable ." + "\n");
								}
							
				}	else
						{
							print ($nodeName + " not found." + "\n");	
						}

			}
						
			if ( startsWith (strip($buffer[0]), "weightedTangents") )
				
			{
				tokenize (strip($buffer[1])) " " $weightedTangents;
				int $weightedTangentsInt = int ($weightedTangents[0]);
				
				if (`objExists $nodeName`)
				{
					keyTangent -weightedTangents $weightedTangentsInt -a -attribute $nodeAttrType[1] $nodeAttrType[0];
				}
			
			}
			
			if ( startsWith (strip($buffer[0]), "lock") )
				
			{
				tokenize (strip($buffer[1])) " " $Lock;
				
				for ($x=0, $y=0; $y <size($Lock), $x < size($allKeyframes) ; $x = $x + 2, $y ++ )
				{
					float $LockString;
					$LockString = float ($Lock[$y]);
					$keyFrame = float ($allKeyframes[$x]);
										
					$keyFrameSet = `findExactKeyframe $firstKeyFrame $currentTime $keyFrame`;
					
					if (`objExists $nodeName`)
					{
						keyTangent -edit -time $keyFrameSet -attribute $nodeAttrType[1] -lock $LockString $nodeAttrType[0];
					}
					
				}
				
			}
			
			if ( startsWith (strip($buffer[0]), "weightLock")  )
				
			{
					tokenize (strip($buffer[1])) " " $weightLock;
					
					for ($x=0, $y=0; $y <size($weightLock), $x < size($allKeyframes) ; $x = $x + 2, $y ++ )
					{
						float $weightLockString;
						$weightLockString = float ($weightLock[$y]);
					
						$keyFrame = float ($allKeyframes[$x]);
						$keyFrameSet = `findExactKeyframe $firstKeyFrame $currentTime $keyFrame`;
						
						if (`objExists $nodeName`)
						{
							if ($weightLockString == 0 )
							{
								keyTangent -time $keyFrameSet -attribute $nodeAttrType[1] -weightLock $weightLockString $nodeAttrType[0];
							}
						}
					}
				
			}

				
			if (startsWith (strip($buffer[0]), "inWeight"))
			{				
				tokenize (strip($buffer[1])) " " $inWeight;
			}			
	
			if (startsWith (strip($buffer[0]), "outWeight"))
			{				
				tokenize (strip($buffer[1])) " " $outWeight;
			}
								
			if (startsWith (strip($buffer[0]), "inAngle"))
			{				
				tokenize (strip($buffer[1])) " " $inAngle;
				if (`objExists $nodeName`)
				{
						for ($x=0, $y=0, $z=0; $x < size($allKeyframes), $y <size($inAngle), $z< size($inWeight) ; $x = $x + 2, $y ++, $z++ )
						{
							
							$keyFrame = float ($allKeyframes[$x]);
							
							$keyFrameSet = `findExactKeyframe $firstKeyFrame $currentTime $keyFrame`;
							
							float $inAngleString;
							$inAngleString = float ($inAngle[$y]);
							float $inWeightString;
							$inWeightString = float ($inWeight[$z]);
							
							keyTangent -time $keyFrameSet -a -inAngle $inAngleString -inWeight $inWeightString -attribute $nodeAttrType[1] $nodeAttrType[0];
						}
							
				}
						
			}
			
			if (startsWith (strip($buffer[0]), "outAngle"))
			{				
				tokenize (strip($buffer[1])) " " $outAngle;
				if (`objExists $nodeName`)
				{
						for ($x=0, $y=0, $z=0; $y <size($outAngle), $x < size($allKeyframes), $z<size($outWeight) ; $x = $x + 2, $y ++, $z++ )
						{
							float $outAngleString;
							$outAngleString = float ($outAngle[$y]);
							float $outWeightString;
							$outWeightString = float ($outWeight[$z]);
							
							$keyFrame = float ($allKeyframes[$x]);
							
							$keyFrameSet = `findExactKeyframe $firstKeyFrame $currentTime $keyFrame`;
							
							keyTangent -time $keyFrameSet  -a -outAngle $outAngleString -outWeight $outWeightString -attribute $nodeAttrType[1] $nodeAttrType[0];
						}
				}
			}
			
			if (startsWith (strip($buffer[0]), "inTangentType"))
			{				
				tokenize (strip($buffer[1])) " " $inTangentType;
				string $inTangentStrings[] = $inTangentType;
				if (`objExists $nodeName`)
				{
						for ($x=0, $y=0; $x < size($allKeyframes), $y < size($inTangentStrings) ; $x = $x + 2, $y++)
						{	
						$keyFrame = float ($allKeyframes[$x]);
						
						$keyFrameSet = `findExactKeyframe $firstKeyFrame $currentTime $keyFrame`;
						
						keyTangent -inTangentType $inTangentStrings[$y] -time $keyFrameSet -attribute $nodeAttrType[1] $nodeAttrType[0];
						}
				}
					
			}
	
			if (startsWith (strip($buffer[0]), "outTangentType"))
			{				
				tokenize (strip($buffer[1])) " " $outTangentType;
				string $outTangentStrings[] = $outTangentType;
				if (`objExists $nodeName`)
				{
						for ($a=0, $b=0; $a < size($allKeyframes), $b < size($outTangentStrings) ; $a = $a + 2, $b++)
						{	
						$keyFrame = float ($allKeyframes[$a]);
						
						$keyFrameSet = `findExactKeyframe $firstKeyFrame $currentTime $keyFrame`;
						
						keyTangent -time $keyFrameSet -outTangentType $outTangentStrings[$b] -attribute $nodeAttrType[1] $nodeAttrType[0];
						}
				}

			}
			
		}
	}
	fclose $fileId;
	
}

//proc to create a directory after user type in a path
global proc as_checkingDirFilesProc()
	
{
		//This is file and directory checking.
		string $dirName =`textField -q -text as_savedirTF`;
		string $anmName =`textField -q -text as_AnmNameTF`;
		global string $outputName;
		
		int $poseRBOnOff = `radioButton -q -sl poseRB`;
		if ($poseRBOnOff == 1)
		{
			$outputName = ($dirName + "/" + $anmName + ".pose");
		} 
		else
		{
			$outputName = ($dirName + "/" + $anmName + ".anm");
		}
		
		//Check if the pose name textfield is given a name.
		if (size($anmName)<1)
		{
		error "Please type in only file name. No need extension.";
		}
		
					int $textDirExist =`filetest -d $dirName`;
					if ($textDirExist==0)
					{
						as_createDirConfirmWinProc;
						//warning "Directory is not created.";
					}
						else
						{
						//if file exists, it will popup a confirmation window or CopyPose rightaway.
							int $fileExist =`filetest -w $outputName`;		
							if ($fileExist == 1) 
								{
									as_overWriteOutputWinProc;
								}
									else
								{
										int $anmRBstate =`radioButton -q -sl anmRB`;
										if ($anmRBstate == 1)
										{
											as_printToFileProc;
										}
								
										else
											{
											ps_printToFileProc;
											
											}
									}
										
							}

					
								
}

//overwrite a file confirmation window
global proc as_overWriteOutputWinProc()

{
	string $output =`textField -q -text as_AnmNameTF`;
	string $confirm;
	int $poseRBOnOff = `radioButton -q -sl poseRB`;
	if ($poseRBOnOff == 1)
	{
	$confirm =`confirmDialog 
						-title "Are you sure?" 
						-message ("File name exists, overwrite " + $output + ".pose" + " ?")
				 		-button "Ok" -button "Cancel" -defaultButton "Ok"
				 		-cancelButton "Cancel" -dismissString "Cancel"`;
	} else
	{
	$confirm =`confirmDialog 
						-title "Are you sure?" 
						-message ("File name exists, overwrite " + $output + ".anm" + " ?")
				 		-button "Ok" -button "Cancel" -defaultButton "Ok"
				 		-cancelButton "Cancel" -dismissString "Cancel"`;
	}
	
		
		if  ($confirm == "Ok")
		{
			int $anmRBstate =`radioButton -q -sl anmRB`;
			if ($anmRBstate == 1)
			{
			as_printToFileProc;
			} else
				{
				ps_printToFileProc;
				}
				
		}

}


//double click the file will open with wordpad, provided that
//the user has associated .pose .anm with Wordpad or textpad
global proc as_doubleClickOpenDataProc()
{
		string $dirName =`textField -q -text as_savedirTF`;
		string $anmName[] =`textScrollList -q -si as_AnmStoringTSL`;
		$outputName = ($dirName + "/" + $anmName[0]);
 		system("load " + $outputName );
}

//proc to select a node when user select the item from the textscrollist.
global proc as_selectSelectedFromTSLProc()
{
	string $seletecdTemp[]=`textScrollList -q -si as_selectedNodeTSL`;
	for ($x=0; $x<size($seletecdTemp); $x++)
	{
	select $seletecdTemp;
	}

}

//proc to delete a file in textscrollist, which remove the file from system too
global proc as_delSelectedTSLFile()
{
	//This will delete the selected file from textscrollist
	string $dirName =`textField -q -text as_savedirTF`;
	string $file[] =`textScrollList -q -si as_AnmStoringTSL`;
	string $output = ($dirName + "/" + $file[0]);
	int $fileExist =`filetest -w $output`;	
	if ($fileExist==1)
	{
	sysFile -del $output;

	as_populateDirFileProc;
	print ("\n" + $output + " is deleted.");
	}
	
	else
	{
		error ("Unable to delete " + $output);
	}

}

global proc as_createDirProc()
	
{
	//This will create a new directory
	string $dir =`textField -q -text as_savedirTF`;
	sysFile -md $dir;
	int $textDirExist =`filetest -d $dir`;
			if ($textDirExist==1)
			{
				int $anmRBstate =`radioButton -q -sl anmRB`;
				if ($anmRBstate == 1)
				{
				as_printToFileProc;
				} 
					else
						{
						ps_printToFileProc;
						}
			}
		else
		{
		error "Create directory failed. Make sure you type in correct format i.e c:\XYZ ..";
		}

}

//This is create directory popup confirmation window.
global proc as_createDirConfirmWinProc()
{
		string $dir =`textField -q -text as_savedirTF`;
		string $confirm =`confirmDialog 
						-title "Create Directory?" 
						-message ("Directory not exists, create " +  $dir + "\n" + "and proceed copying?")
				 		-button "Ok" -button "Cancel" -defaultButton "Ok"
				 		-cancelButton "Cancel" -dismissString "Cancel"`;
		
		if  ($confirm == "Ok")
		{
		as_createDirProc ;
		}
				
}

global proc copyPoseCommandProc()
{
	button -e -label "Copy Pose" -h 30 -w 100 -bgc 0.8 0.8 0.8 -c as_checkingDirFilesProc copyToFileButton;
	//textField -edit -text $anmPoseuserDir -enterCommand as_populateDirFileProc as_savedirTF;
	button -e -label "Paste Pose" -h 30 -w 95 -bgc 0.65 0.65 0.65 -c ps_pastePoseFromFile pasteToSceneButton;
	checkBox -e -en 0 -v 0 -label "incl. cameras" inclcamCB;
	checkBox -e -en 0 -v 0 -label "incl. constraints" inclcstCB;
	radioButton -e -vis 0 -en 0 -label "All" copyAllRB;
 	radioButton -e -vis 0 -en 0 -label "Time Slider" timeRangeRB;
 	text -e -vis 0 chooseAFrameT;
 	text -e -vis 0 timeRange2PasteT;
	as_populateDirFileProc;
}
	
global proc copyAnmCommandProc()
{
	button -e -label "Copy Animation" -h 30 -w 100 -bgc 0.8 0.8 0.8 -c as_checkingDirFilesProc copyToFileButton;
	//textField -edit -text $anmPoseuserDir -enterCommand as_populateDirFileProc as_savedirTF;
	button -e -label "Paste Animation" -h 30 -w 95 -bgc 0.65 0.65 0.65 -c as_pasteAnmProc pasteToSceneButton;
	checkBox -e -en 1 -label "incl. cameras" inclcamCB;
	checkBox -e -en 1 -v 0 -label "incl. constraints" inclcstCB;
	radioButton -e -vis 1 -en 1 -label "All" copyAllRB;
 	radioButton -e -vis 1 -en 1 -label "Time Slider" timeRangeRB;
 	text -e -vis 1 chooseAFrameT;
 	text -e -vis 1 timeRange2PasteT;
	as_populateDirFileProc;
}

global proc expandlistedOnlyframeLayout()
{
	int $checkCB =`checkBox -q -v copylistedCB`;
	if ($checkCB == 1)
	{
	frameLayout -e -vis true -w 220 -label "Copy Listed Nodes" -cll true -cl false listedOnlyFL;
	window -e -w 235 -h 650 -s true -t "Animation Copy" my_AnmCopyWindow;
	} else
		{
		frameLayout -e -vis false -w 220 -label "Copy Listed Nodes" -cll true -cl true listedOnlyFL;
		window -e -w 235 -h 450 -s true -t "Animation Copy" my_AnmCopyWindow;	
		}
}

	
//===================Pose Copy======================//
//====Written by Sin========sinl@backb.com==========//
//=====================Copy Pose====================//

global proc ps_printToFileProc ()
	
{
	sin_setAsDefaultDir;
	int $checkCB = `checkBox -q -v copylistedCB`;	
	string $allKeyNodes[];
	if ($checkCB == 1)
	{
		$allKeyNodes = ps_findSelectedNodesProc();
		if (size($allKeyNodes)<1)
		{
		error "Nothing is in the list.";
		}
	} else
	
	{
		//gets all nodes want to copy
		$allKeyNodes = ps_findNodesWithKeysProc();
	}
		//check system directory
		global string $dirname;
		$dirName =`textField -q -text as_savedirTF`;
		string $poseName =`textField -q -text as_AnmNameTF`;
		
		global string $outputName;
		$outputName = ($dirName + "/" + $poseName + ".pose");
		
		//After the error checking and confirm, the exists file will be deleted.
		int $fileExist =`filetest -f $outputName`;
		print $fileExist;
		if ($fileExist == 1) 
			{										
				sysFile -delete $outputName;
			}	
			
					//Start printing to file
					$fileId=`fopen $outputName`;
					fprint $fileId "\n";
					fclose $fileId;
								
								for ($i =0; $i <size($allKeyNodes); $i++)
									{
																	
										$fileId=`fopen $outputName`;
										float $allKeyNodesValue = `getAttr $allKeyNodes[$i]`;
										string $nodesOutput = ($allKeyNodes[$i] + " , " + $allKeyNodesValue +  "\n");
										print $nodesOutput;
													
										fprint $fileId $nodesOutput;
										fclose $fileId;
										
									}
							//populate new filelist		
							as_populateDirFileProc;
							textScrollList -e -si ($poseName + ".pose") as_AnmStoringTSL;							
							print ("Total Copied Nodes :" + `size($allKeyNodes)`);						
}	


	
global proc string [] ps_findNodesWithKeysProc()

{
	//This will return nodes and thier attributes
	string $returnAllKeyNodes[];
	string $allnode[] =`ls -type transform`;
	string $lsConstraintRemoved[] =`ls -type constraint`;
	
	string $allnode [] =stringArrayRemoveExact($lsConstraintRemoved, $allnode);
			
	for ($x=0; $x<size($allnode) ; $x++)
		{
		int $allNodeKeysNum=`keyframe -q -keyframeCount $allnode[$x]`;
		if ($allNodeKeysNum > 0)
				{
					string $attrOnly[] =`listAttr -k $allnode[$x]`;
						for ($y=0; $y<size($attrOnly); $y++)
						{
							
							string $nodesAttrs =$allnode[$x] + "." + $attrOnly[$y];
								
									int $singleNodeKeysNum=`keyframe -q -keyframeCount $nodesAttrs`;
							
									if ($singleNodeKeysNum> 0)
										{
											$returnAllKeyNodes[size($returnAllKeyNodes)] = $nodesAttrs;
										}
														
						}
				
				}
				
		}
	
	return $returnAllKeyNodes;

}

global proc string [] ps_findSelectedNodesProc()

{
	//This will return nodes and thier attributes
	string $returnSelectedNodes[];
	string $allnode[] =`textScrollList -q -ai as_selectedNodeTSL`;

	for ($x=0; $x<size($allnode) ; $x++)
		{
		string $attrOnly[] =`listAttr -k $allnode[$x]`;
			for ($y=0; $y<size($attrOnly); $y++)
				{
							
				string $nodesAttrs =$allnode[$x] + "." + $attrOnly[$y];
				$returnSelectedNodes[size($returnSelectedNodes)] = $nodesAttrs;
														
				}
				
		}
	
	return $returnSelectedNodes;

}



//=======================Paste Pose================================//

global proc ps_pastePoseFromFile()
	
{
	//Pasting the pose to the maya scene
	string $dirName =`textField -q -text as_savedirTF`;
	string $fileName[] =`textScrollList -q -si as_AnmStoringTSL`;
	if (size($fileName)<1)
	{
		error "Select a pose.";
	}
	
	
	$fileId=`fopen ($dirName + "/" + $fileName[0]) "r"`;

 	
	string $allKeyNodes[];
		
 	while ( !`feof $fileId` ) 
		{ 
	 		string $nextLine = `fgetline $fileId`;
			
			if ( size( $nextLine ) > 0 )
			{
				$allKeyNodes[0] = $nextLine;
				
				if (size ($allKeyNodes[0]) > 1)
				{
					string $buffer[];
					tokenize $allKeyNodes[0] "," $buffer;
				
					//tokenize to nodes and values;
					string $getOnlyNodes = $buffer[0];
					float $getOnlyValues = float ($buffer[1]);
					
			//check if the attribute is setable by setAttr, and if object exists
					
					if (`objExists $getOnlyNodes`)
					{
						int $setableBoo = `getAttr -se $getOnlyNodes`;
					
						if ($setableBoo == 1)
								{
									setAttr $getOnlyNodes $getOnlyValues;
									setKeyframe $getOnlyNodes;
									print ("set " + $getOnlyNodes + " = " + $getOnlyValues + "\n");
									
								}
					}
				}
			}
		
		}
fclose $fileId;
//scriptEditorInfo -se 0 -sw 0 -si 0 -sr 0;
print "Result: Processed.";
}


//==========================================================//
//=================Animation Transfer=======================//
//===========================================================//


//=======================================================================================================//
//=================================   Directory      ====================================================//
//=======================================================================================================//
//=======================================================================================================//

//updating the checkBox buttons that list out .ma or .mb files
global proc refreshcbStateProc()
{
	textScrollList -e -ra sourceBatchTSL;
	int $cbmastate = `checkBox -q -v cballma`;
	int $cbmbstate = `checkBox -q -v cballmb`;
	string $sourceFolderTF =`textField -q -text sourceTF`;
	string $fileList1[];
	string $fileList2[];
	
	if ($cbmastate == 1 && $cbmbstate == 0)
	{
	$fileList1 =`getFileList -folder ($sourceFolderTF + "/") -filespec "*.ma"`;	
	}
	
	if ($cbmastate == 0 && $cbmbstate == 1)
	{
	$fileList1 =`getFileList -folder ($sourceFolderTF + "/") -filespec "*.mb"`;	
	}
	
	if ($cbmbstate == 1 && $cbmastate == 1)
	{
	$fileList1 =`getFileList -folder ($sourceFolderTF + "/") -filespec "*.mb"`;
	$fileList2 =`getFileList -folder ($sourceFolderTF + "/") -filespec "*.ma"`;
	$fileList1 = `stringArrayCatenate $fileList1 $fileList2`;
	}
		
	for ($eachfileList in $fileList1)
		{
		textScrollList -e -append $eachfileList sourceBatchTSL;
		}
	selectAllProc;
}

global proc pickDirectoryProc( string $filename, string $fileType )
{
	int $cbmastate = `checkBox -q -v cballma`;
	int $cbmbstate = `checkBox -q -v cballmb`;
	string $fileList1[];
	string $fileList2[];
	
	if ($cbmastate == 1 && $cbmbstate == 0)
	{
	$fileList1 =`getFileList -folder ($filename + "/") -filespec "*.ma"`;	
	}
	
	if ($cbmastate == 0 && $cbmbstate == 1)
	{
	$fileList1 =`getFileList -folder ($filename + "/") -filespec "*.mb"`;	
	}
	
	if ($cbmbstate == 1 && $cbmastate == 1)
	{
	$fileList1 =`getFileList -folder ($filename + "/") -filespec "*.mb"`;
	$fileList2 =`getFileList -folder ($filename + "/") -filespec "*.ma"`;
	$fileList1 = `stringArrayCatenate $fileList1 $fileList2`;
	}
		
	textScrollList -e -ra sourceBatchTSL;

	for ($eachfileList in $fileList1)
		{
		textScrollList -e -append $eachfileList sourceBatchTSL;
		}
	
	textField -e -text $filename sourceTF;

}


global proc pickDirProc()
{

	if (`checkBox -q -v cbbf`==1)
	{

	fileBrowserDialog -m 4 -fc "pickDirectoryProc" -an "Pick a directory" -om "Import";
		selectAllProc;

	}
else 
	
		{
		textScrollList -e -ra sourceBatchTSL;
		string $path =`fileDialog -directoryMask "/user/*.ma;*.mb"`;
		string $singlefilename =basename( $path, "" );
 		string $singlepath = dirname( $path );
		textField -e -text $singlepath sourceTF;
		textScrollList -e -append $singlefilename sourceBatchTSL;
		selectAllProc;
		}

}


global proc savedToPickDirProc()
{
fileBrowserDialog -m 4 -fc "savedToDirProc" -an "Pick a directory" -om "Import";
}

global proc savedToDirProc( string $filename, string $fileType )
	
{
textField -e -text ($filename +"/") savedToTF;
}	


global proc targetAcqProc()
{
	string $singlesource =`fileDialog -directoryMask "/user/*.ma;*.mb"`;
	textField -e -text $singlesource targetRigTF;
}

global proc savedToProc()
{
	string $singlesource =`fileDialog -directoryMask "/user/*.ma;*.mb"`;
	textField -e -text $singlesource savedToTF;
}


global proc sourceAcqProc()
{
	string $singlesource =`fileDialog -directoryMask "/user/*.ma;*.mb"`;
	textScrollList -e -ra sourceBatchTSL;
	textScrollList -e -append $singlesource sourceBatchTSL;
}


global proc directoryProc()
{
	if (`checkBox -q -v cbbf`==1)
	{
	 checkBox -e -en true cbsl;
	 checkBox -e -en 1 cballma;
	checkBox -e -en 1 cballmb;
	}
else
	{
	checkBox -e -en false cbsl;
	checkBox -e -en 0 cballma;
	checkBox -e -en 0 cballmb;
	}
}

global proc selectAllProc()
{
	if (`checkBox -q -v cbsl`==1)
	{
	
		string $allitemsource[]=`textScrollList -q -ai sourceBatchTSL`;
		for ($eachitem in $allitemsource)
		
		{
			textScrollList -e -si $eachitem sourceBatchTSL;
		}
	}	
	else
			
		{
			textScrollList -e -da sourceBatchTSL;
		}	
	
}


global proc clearListProc()
{
textScrollList -e -ra sourceBatchTSL;
}

//=======================================================================================================//
//==============================       Animation Transfer    =============================================//
//=======================================================================================================//
//=======================================================================================================//


global proc string[] getNodesFromNamespace (string $nodes[])

{
               string $returnBuffer[];
               for ($i = 0; $i < size($nodes);$i++)
                {
					string $buffer[];
                    tokenize $nodes[$i] ":" $buffer;
                    $returnBuffer[$i] = $buffer[(size($buffer) - 1)];
                 }             
               return $returnBuffer;
}

global proc AnmTransfer()
{
		
	global string $sourceFolderTF;
	global string $tfSavedTo;
		
	//Target File/Rig
	$tfTarget = `textField -q -text targetRigTF`;
	//Saved to Directory
	$tfSavedTo =`textField -q -text savedToTF`;
	//Source folder
	$sourceFolderTF =`textField -q -text sourceTF`;
	//Prefix and Suffix that will rename to the saved files
	$suffixTF =`textField -q -text suffixTF`;
	$prefixTF =`textField -q -text prefixTF`;

	//Source animation files	
	string $tfSource []= `textScrollList -q -si sourceBatchTSL`;
	
	if(!`filetest -d $tfSavedTo`)
	sysFile -makeDir $tfSavedTo;

			

for ($z=0; $z<size($tfSource); $z++)
  {	

	performNewScene 0;
	string $Sourceimport = $sourceFolderTF +"/" + $tfSource[$z];
	string $saveFilename = `basenameEx $Sourceimport`;
	
		//importing the Source file
	file -import 
	-ra false 
	-namespace "Source" $Sourceimport;
	
	//importing Target rig
	file -import 
	-ra false 
	-namespace "Target" $tfTarget;
	
	//find all the transform nodes and tokenize "Source:"
	string $allSource[] =`ls -type transform "Source:*"`;
	string $nodesCopy[]=`getNodesFromNamespace ($allSource)`;
	
	//set timerange as per the source files
	selectKey -time ":" $allSource;
	float $allKeys[] = sort(`keyframe -q -sl`);
	playbackOptions -min $allKeys[0] -max $allKeys[(size($allKeys) -1)];
	select -cl;
	
	//find which node has more than 1 keys, copying those attributes and paste
	for ($x=0; $x<size($nodesCopy); $x++)
	{
	int $keyframenum=`keyframe -q -keyframeCount ("*Source:" + $nodesCopy[$x] + "*")`;
	if ($keyframenum > 0)
		{	
			copyKey -time ":" -float ":" -hierarchy none -controlPoints 0 -shape 1 ("*Source:" + $nodesCopy[$x] + "*");
			if( `objExists ("Target:" + $nodesCopy[$x] + "*")` )
				{
				pasteKey -time 1 -float 1 -option "replaceCompletely" {"*Target:" + $nodesCopy[$x] + "*"};
		
 				} 
		}
	}
//delete and remove prefix
group -n groupTemp "Source:*"  ;
delete groupTemp;
namespace -f -mv "Target" ":";
namespace -rm "Target";

//save the finished files to
file -rename ($tfSavedTo + $prefixTF + $saveFilename + $suffixTF);file -save -type "mayaAscii";
	
  }	
  
}


//===============================================================//	
//===============================================================// 
//====================== Animation Copy Window===================//	
//===============================================================//	
//===============================================================//	

global proc my_AnmCopyWindowProc()
{

if (`window -exists my_AnmCopyWindow`)
	{
		deleteUI my_AnmCopyWindow;
		windowPref -remove my_AnmCopyWindow;
	}
	
window -w 238 -h 450 -s true -maximizeButton 0 -t "Animation Copy" -le 900 my_AnmCopyWindow;	
	 	
	string $anmCopytabs = `tabLayout -innerMarginWidth 1 -innerMarginHeight 5 -scrollable false`;
	
string $child1 =`columnLayout -adj false`;

frameLayout -w 220 -label "Store Animation Keys" -cll true -cl false;
	
columnLayout -adj false;
	
	separator -w 220 -h 3 -style "in";
	separator -w 220 -h 3 -style "none";
	
	rowColumnLayout 
				-numberOfColumns 2 
				-columnAttach 1 "both" 20
			 	-columnWidth 1 120 
				-columnWidth 2 80;
	
		radioCollection PoseAnimationRBC;
 		radioButton -w 100 -sl -label "Pose" -onCommand copyPoseCommandProc poseRB;
 		radioButton -w 100 -label "Animation" -onCommand copyAnmCommandProc anmRB; 
	setParent..;
	
	separator -w 220 -h 3 -style "in";
	separator -w 220 -h 3 -style "none";
	
	rowColumnLayout 
	-numberOfColumns 3
	-columnAttach 1 "left" 5
	-columnWidth 1 60 
	-columnWidth 2 20 
	-columnWidth 3 135;
 
	text -label "Saved Dir.";
 	button -bgc 0.8 0.8 0.8 -l ".." -c as_pickDirProc;
	textField -enterCommand textFieldEnterCommand as_savedirTF;
	setParent..;

		rowColumnLayout 
		-numberOfColumns 3 
		-columnAttach 1 "left" 5
	 	-columnWidth 1 80 
		-columnWidth 2 135; 
	
		text -label "File Name :";
		textField as_AnmNameTF;
		
		setParent..;
	
			separator -style "none";
							
					
				rowColumnLayout -nc 4 -cw 1 110 -cw 2 105;
			
					frameLayout -mw 3 -mh 3 -lv false -bs "etchedOut";
						columnLayout -w 110 -adj false;
							
							radioCollection; 							
 							radioButton -vis 0 -sl -en 0 -label "All" copyAllRB;
 							radioButton -vis 0 -en 0 -label "Time Slider" timeRangeRB;
							separator -style "none";					
							button -label "Copy Pose" -h 30 -w 100 -bgc 0.8 0.8 0.8 -c as_checkingDirFilesProc copyToFileButton;
							separator -h 3 -style "none";
							checkBox -label "Listed Only" -cc expandlistedOnlyframeLayout copylistedCB;
							separator -w 220 -h 3 -style "in";
							checkBox -en 0 -label "incl. cameras" inclcamCB;
							checkBox -en 0 -v 0 -label "incl. constraints" inclcstCB;
						setParent..;
					setParent..;
					
					frameLayout -mh 3 -mw 3 -h 94 -lv false -bs "etchedOut";
						columnLayout -w 110 -adj false;
							
							radioCollection;
 							text -vis 0 -l "Choose a frame in" chooseAFrameT;
 							text -vis 0 -label "time slider to paste" timeRange2PasteT;
 							separator -style "none";
							button -label "Paste Pose" -h 30 -w 95 -bgc 0.65 0.65 0.65 -c ps_pastePoseFromFile pasteToSceneButton;
							separator -h 18 -style "none";
							separator -w 100 -style "in";
							separator -style "none";
							button -label "Delete" -h 30 -w 95 -bgc 1 0.992 0.656 -c as_deleteConfirmWinProc;
						setParent..;
					setParent..;
													
			setParent..;

			separator -h 3 -style "none";
		
			textScrollList -h 152 -w 210 -selectCommand as_fillDirNameProc -doubleClickCommand as_doubleClickOpenDataProc as_AnmStoringTSL;
			
			separator -h 3 -style "none";

			separator-h 3 -style "none";
				

	frameLayout -w 220 -vis false -label "Copy Listed Nodes" -cll true -cl true listedOnlyFL;
	
	columnLayout -adj false;
	separator -w 210 -h 3 -style "in";
	separator -w 210 -h 3 -style "in";
	
			rowColumnLayout 
				-numberOfColumns 3 
				-columnAttach 1 "both" 0
			 	-columnWidth 1 75
				-columnWidth 2 75 
				-columnWidth 3 60;
				button -label "+" -bgc 0.65 0.65 0.65 -c as_addSelectedProc addButton;
				button -label "-" -bgc 0.8 0.8 0.8 -c as_removeSelectedProc removeButton;
				button -label "Clear List" -bgc 1 0.992 0.656 -c as_clearListSelectedNodeTSLProc;
			
			setParent..;
			
		separator -h 3 -style "none";
				
		textScrollList -allowMultiSelection true -h 150 -w 210 -sc as_selectSelectedFromTSLProc as_selectedNodeTSL;
					
				//separator -w 220 -h 3 -style "none";
				//separator -w 220 -h 3 -style "none";
			setParent..;
	
setParent..;
setParent..;
setParent..;
setParent..;

  //=========Second tab : Animation Transfer==============//


string $child2 = `columnLayout -adj true`;

frameLayout -w 220 -label "Animation Transfer" -cll true -cl false;
	
columnLayout -adj true;

separator -w 220 -h 3 -style "in";

	rowColumnLayout 
		-numberOfColumns 3 
		-columnAttach 1 "left" 5
		-columnWidth 1 70 
		-columnWidth 2 20 
		-columnWidth 3 128;
	 	text -label "Target File...";
	 	button -l ".." -c targetAcqProc;
		textField targetRigTF;
	
	 	text -label "Saved Dir.";
	 	button -l ".." -c savedToPickDirProc;
		textField -text "c:/temp/" savedToTF;
	setParent..;
	
	rowColumnLayout 
		-numberOfColumns 5 
		-columnAttach 1 "left" 10
		-columnWidth 1 70
		-columnWidth 2 30 
		-columnWidth 3 40 
		-columnWidth 4 28
		-columnWidth 5 49;
		text -label "add";
	 	text -label "prefix";
	 	textField prefixTF;
		text -label "suffix";
	 	textField -text "_new" suffixTF;
		
	setParent..;


	rowColumnLayout 
	-numberOfColumns 3 
	-columnAttach 1 "left" 10
 	-columnWidth 1 70 
	-columnWidth 2 20 
	-columnWidth 3 128; 

	text -label "Source....";
	button -l ".." -c pickDirProc;
	textField sourceTF;
	
	setParent..;
	
	rowColumnLayout 
	-numberOfColumns 3 
	-columnAttach 1 "left" 10
 	-columnWidth 1 70 
	-columnWidth 2 80 
	-columnWidth 3 90; 

	text -label "check if";
	checkBox -l "batch files" -v 1 -cc directoryProc cbbf;
	checkBox -l "select all" -en true -value 1 -cc selectAllProc cbsl;
	
	text -label "file type";
	checkBox -l ".ma" -v 1 -cc refreshcbStateProc cballma;
	checkBox -l ".mb" -v 1 -cc refreshcbStateProc cballmb;
	

	setParent..;

	separator -style "in";
	separator -style "in";

	rowColumnLayout 
	-numberOfColumns 2 
	-columnAttach 1 "both" 0
 	-columnWidth 1 160 
	-columnWidth 2 57;
	button -h 30 -label "Copy" -bgc 0.8 0.8 0.8 -c AnmTransfer;
	button -label "Clear list" -bgc 1 0.992 0.656 -c clearListProc;

	setParent..;

	separator -style "in";

	columnLayout -adj true;
	textScrollList -h 200 -allowMultiSelection true sourceBatchTSL;
	setParent..;

setParent..;
setParent..;

setParent..;

tabLayout -edit	-tabLabel $child1 "Copy" -tabLabel $child2 "Transfer" $anmCopytabs;

showWindow my_AnmCopyWindow;
checkAnmPrefstatus;
sin_readAnmPose_userPrefs;
as_populateDirFileProc;
}